With this shader you can reuse your skybox cubemap for reflection materials. The built-in shader gives nice results but using the cubemap from the skybox, the coordinates are inverted. Here's a modified version of the built-in Reflect-Glossy shader.

Shader "WB/WB-Skybox Reflection" {
Properties {
	_Color ("Main Color", Color) = (1,1,1,1)
	_ReflectColor ("Reflection Color", Color) = (1,1,1,0.5)
	_SpecColor ("Specular Color", Color) = (0.5, 0.5, 0.5, 1)
	_Shininess ("Shininess", Range (0.01, 1)) = 0.078125
	_MainTex ("Base (RGB) RefStrength (A)", 2D) = "white" {} 
	_Cube ("Reflection Cubemap", Cube) = "_Skybox" { TexGen CubeReflect }
	_CoordVector ("Coord Vector", Vector) = (-1, 1, 1, 0)
}
SubShader {
	LOD 200
	Tags { "RenderType"="Opaque" }
	
	CGPROGRAM
	#pragma surface surf BlinnPhong

	sampler2D _MainTex;
	samplerCUBE _Cube;

	fixed4 _Color;
	fixed4 _ReflectColor;
	
	half _Shininess;
	
	fixed4 _CoordVector;

	struct Input {
		float2 uv_MainTex;
		float3 worldRefl;
	};

	void surf (Input IN, inout SurfaceOutput o) {
		fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
		fixed4 c = tex * _Color;
		o.Albedo = c.rgb;
		o.Gloss = tex.a;
		o.Specular = _Shininess;
		float3 worldRefl_Inverted = IN.worldRefl;
		worldRefl_Inverted.x *= _CoordVector.x;
		worldRefl_Inverted.y *= _CoordVector.y;
		worldRefl_Inverted.z *= _CoordVector.z;
		fixed4 reflcol = texCUBE (_Cube, worldRefl_Inverted);
		reflcol *= tex.a;
		o.Emission = reflcol.rgb * _ReflectColor.rgb;
		o.Alpha = reflcol.a * _ReflectColor.a;
	}
	ENDCG
}
	
FallBack "Reflective/VertexLit"
} 

With the default settings the x-axis gets inverted, but if it doesn't get you the result expected, try modifying the x, y and z values of the "Coord Vector" property to "1" or "-1" respectively. Hope it helps!